function cargar_bombas()
	load sound "sfx\dbomb.wav",10
	load sound "sfx\exp1.wav",11
	
	snd_exp1=11
	snd_bmb1=10
   for i = 0 to 10
      bombas(i).objeto=cargar_modelo("media\bomb.x")
      hide object bombas(i).objeto
   next i
endfunction

function crear_bomba(cx as integer, cz as integer)
   for i = 0 to 10
      if bombas(i).activa=0 then exit
   next i

   if i>10 then return

   bombas(i).activa=1
   bombas(i).initim=timer()
   bombas(i).chocada=1
   position object bombas(i).objeto,cx*16,0,-cz*16
   show object bombas(i).objeto
	play sound snd_bmb1
endfunction

function controlar_bombas()
   for i = 0 to 10
      if bombas(i).activa=1

			atim=timer()-bombas(i).initim
			
			esca=(atim*255)/2000
			
         if timer()-bombas(i).initim>2000
            explotar_bomba(i)
         endif
      endif
   next i
endfunction

function explotar_bomba(n as integer)
	bombas(n).activa=0
	hide object bombas(n).objeto
	play sound 11
	cx=get_cuadro(object position x(bombas(n).objeto))
	cz=get_cuadro(object position z(bombas(n).objeto))
	izq=1
	der=1
	up=1
	ab=1
	
		rem explosiones horiz
		for i = 1 to jugador(1).powbomba
				if cx-i > -1 and izq=1
					rem si no se sale del mapa y no hay obstaculos dibuja
					if cuadros(cz,cx-i).objeto = 0
						crear_explosion(cx-i,cz)
					else
						if cuadros(cz,cx-i).mat=2
							explotar_cuadro(cz,cx-i)
							crear_explosion(cx-i,cz)
						endif
						izq=0
					endif
				endif
				
				if cx+i <35 and der=1
					if cuadros(cz,cx+i).objeto=0
						crear_explosion(cx+i,cz)
					else
						if cuadros(cz,cx+i).mat=2
							explotar_cuadro(cz,cx+i)
							crear_explosion(cx+i,cz)
						endif
						der=0
					endif
				endif
		next i

		rem explosiones vert
		for i = 1 to jugador(1).powbomba
				if cz-i > -1 and up=1
					rem si no se sale del mapa y no hay obstaculos dibuja
					if cuadros(cz-i,cx).objeto = 0
						crear_explosion(cx,cz-i)
					else
						if cuadros(cz-i,cx).mat=2
							crear_explosion(cx,cz-i)
							explotar_cuadro(cz-i,cx)
						endif
						up=0
					endif
				endif
				
				if cz+i < 13 and ab=1
					rem si no se sale del mapa y no hay obstaculos dibuja
					if cuadros(cz+i,cx).objeto = 0
						crear_explosion(cx,cz+i)
					else
						if cuadros(cz+i,cx).mat=2
							crear_explosion(cx,cz+i)
							explotar_cuadro(cz+i,cx)
						endif
						ab=0
					endif
				endif

		next i

		crear_explosion(cx,cz)
endfunction

function cuenta_bombas()
   for i = 0 to 10
      if bombas(i).activa=1
         inc bcount
      endif
   next i
endfunction bcount

function explotar_bombas()
	for i = 0 to 10
		if bombas(i).activa=1
			explotar_bomba(i)
		endif
	next i
endfunction
 